12/Sep/2015

Programando un Arduino remotamente con el mÃ³dulo ESP8266

Programando un Arduino remotamente con el módulo ESP8266

Una de mis viejas aspiraciones cuando construyo robots es poder programarlos sin tener que recogerlos, enchufarles un cable usb o un programador ICSP y volverlos a dejar en su sitio.

En este artículo explicaré cómo con un Arduino UNO y un módulo ESP8266 (llamado WI07C) se puede programar un sketch de Arduino en la placa sin tener que estar cerca de esta, todo mediante wifi y sockets tcp/ip.

Descripción general

<iframe width="560" height="315" src="https://www.youtube.com/embed/JYGhlOkNins?rel=0&showinfo=0" frameborder="0" allowfullscreen></iframe>

Como se puede ver en el vídeo tenemos un Arduino UNO conectado a un display HD44780 y a un módulo wifi ESP8266. Arduino envía cadenas hello world al servidor sockettest que está escuchando por el puerto 49000. Se modifica el código Arduino en el IDE poniendo hello folks, se compila y el fichero .hex generado (se puede ver donde está activandolo en Archivo/Preferencias/compilación) se copia a la carpeta del programa en python. Cuando Arduino recibe un comando reboot se conecta al servidor python por el puerto 50000 entrando en modo de datos, acto seguido se reinicia y empieza la programación remota de Arduino. El proceso se reliza dos veces en el vídeo.

Lo que se aprovecha es el método que tiene Arduino para programarse, ya que usando el puerto serie después de un reset se puede programar un Arduino si se sigue el protocolo STK500 implementado en el bootloader.

Esquema de conexiones

El Arduino y el display HD44780 se alimentan a 5 voltios, el módulo ESP8266 se alimenta a 3,3 voltios. Como el pin rx del módulo wifi sólo puede funcionar a 3,3V se usa un diodo zener de 3,3 voltios junto con una resistencia de 100 Ω.

En las placas Arduino, el pin de reset del microcontrolador está conectado a una resistencia y esta a su vez está conectada a VCC, con lo que para el microcontrolador el pin está a nivel alto. Cuando se pulsa el botón de reset lo que se hace es derivar la corriente hacia masa (ya que el bóton está conectado a esta) y el microcontrolador, al estar a nivel bajo el pin de reset, realiza un reseteo. Cuando el microcontrolador arranca, todos los pines están configurados como entradas (alta impedancia) y por eso no le afecta que el pin de reset esté conectado directamente al pin 12. Si se configura el pin 12 como salida y luego se conecta a masa (nivel bajo o LOW) se provoca el mismo efecto que si se pulsase el botón de reset, además, al existir la resistencia anteriormente mencionada, no hay que preocuparse de que se produzca un cortocircuito al unir VCC con masa (GND).

Sketch de Arduino

// Copyright (C) 2014 SISTEMAS O.R.P.
//
// This program is free software: you can redistribute it and/or modify
// it under the terms of the GNU General Public License as published by
// the Free Software Foundation, either version 3 of the License, or
// (at your option) any later version.
//
// This program is distributed in the hope that it will be useful,
// but WITHOUT ANY WARRANTY; without even the implied warranty of
// MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
// GNU General Public License for more details.
//
// You should have received a copy of the GNU General Public License
// along with this program.  If not, see <http://www.gnu.org/licenses/>.

#include <LiquidCrystal.h>

#define SEARCH_AFTER_RESET "ready"
#define INTRO "\r\n"

#define AP_NORMAL "SISTEMASORP"
#define PWD_NORMAL "mypassword"
#define HOST_NORMAL "192.168.1.33"
#define PORT_NORMAL "49000"

#define AP_BOOTLOADER "SISTEMASORP"
#define PWD_BOOTLOADER "mypassword"
#define HOST_BOOTLOADER "192.168.1.33"
#define PORT_BOOTLOADER "50000"


boolean ok = false;
int counter = 0;
LiquidCrystal lcd(2, 3, 4, 5, 6, 7);
//-----------------------------------------------------------------------------------------------------------------------------------
/*
Parameters:
  show: The string to be printed.
Returns: 
  Nothing.
Description: 
  It clears the LCD and print the string.
*/
void print_lcd(String show)
{
  lcd.clear();
  lcd.print(show);
}
//-----------------------------------------------------------------------------------------------------------------------------------
/*
Parameters:
  command: The string to send.
  timeout: The maximum time in milliseconds the function can be running before a time out.
  wait_for1: The search string when the command succeeded.
  wait_for1: The search string when the command failed.
Returns: 
  The string contained in wait_for1, wait_for2 or the string TIMEOUT.
Description: 
  It sends the command trough the serial port and waits for one of the expected strings or exit with timeout
*/
String send(String command, int timeout, String wait_for1, String wait_for2)
{
  unsigned long time = millis();
  String received = "";
  
  Serial.print(command);
  Serial.print(INTRO);
  
  while(millis() < (time + timeout))
  {
    if(Serial.available() > 0)
    {
      received.concat(char(Serial.read()));
      if(received.indexOf(wait_for1) > -1)
      {
        return wait_for1;
      }
      else if(received.indexOf(wait_for2) > -1)
      {
        return wait_for2;
      }
    }
  }
  
  return "TIMEOUT";
}
//-----------------------------------------------------------------------------------------------------------------------------------
/*
Parameters:
  wait_for: The search string.
  timeout: The maximum time in milliseconds the function can be running before a time out.
Returns: 
  True if the string was found, otherwise False.
Description: 
  It waits for the expected string.
*/
boolean look_for(String wait_for, int timeout)
{
  unsigned long time = millis();
  String received = "";
  
  while(millis() < (time + timeout))
  {
    if(Serial.available() > 0)
    {
      received.concat(Serial.readString());
      if(received.indexOf(wait_for) > -1)
      {
        return true;
      }
    }
  }
  
  return false;
}
//-----------------------------------------------------------------------------------------------------------------------------------
/*
Parameters:
  command: The string to send.
  timeout: The maximum time in milliseconds the function can be running before a timeout.
  wait_for1: The search string when the command succeeded.
  wait_for1: The search string when the command failed.
Returns: 
  True if the wait_for1 string was found, otherwise False.
Description: 
  It sends the command trough the serial port and waits for one of the expected strings or exit with timeout.
*/
boolean send_command(String command, int timeout, String wait_for1, String wait_for2)
{
  String state;
  
  state = send(command, timeout, wait_for1, wait_for2);
  if(state == wait_for1)
  {
    return true;
  }
  else if(state == wait_for2)
  {
    // do something on error
  }
  else
  {
    // do something on timeout
  }
  
  return false;
}
//-----------------------------------------------------------------------------------------------------------------------------------
/*
Parameters:
  Nothing
Returns: 
  True if all commands were successfully, otherwise False.
Description: 
  It initializes the module, joins to the access point and connects to the server.
*/
boolean init_commands()
{
  print_lcd("Changing mode");
  if(send_command("AT+CWMODE=1", 5000, "OK", "ERROR"))
  {
    print_lcd("Resetting module");
    if (send_command("AT+RST", 5000, SEARCH_AFTER_RESET, "ERROR"))
    {
      print_lcd("Joining AP");
  
      String cwjap = "AT+CWJAP=\"";
      cwjap += AP_NORMAL;
      cwjap += "\",\"";
      cwjap += PWD_NORMAL;
      cwjap += "\"";
      if (send_command(cwjap, 20000, "OK", "FAIL"))
        if (send_command("AT+CIPMUX=0", 2000, "OK", "ERROR"))
          if (send_command("AT+CIPMODE=0", 2000, "OK", "ERROR"))
          {
            print_lcd("Connecting host");
            
            String cipstart = "AT+CIPSTART=\"TCP\",\"";
            cipstart += HOST_NORMAL;
            cipstart += "\",";
            cipstart += PORT_NORMAL;
            if (send_command(cipstart, 5000, "OK", "ERROR"))
              return true;
          }
    }
  }
            
  return false;
}
//-----------------------------------------------------------------------------------------------------------------------------------
/*
Parameters:
  Nothing
Returns: 
  True if all commands were successfully, otherwise False.
Description: 
  It initializes the module, joins to the access point, connects to the server and starts the protocol.
*/
boolean boot_commands()
{
  print_lcd("Joining AP");
  
  String cwjap = "AT+CWJAP=\"";
  cwjap += AP_BOOTLOADER;
  cwjap += "\",\"";
  cwjap += PWD_BOOTLOADER;
  cwjap += "\"";
  if (send_command(cwjap, 20000, "OK", "FAIL"))
    if (send_command("AT+CIPMUX=0", 2000, "OK", "ERROR"))
      if (send_command("AT+CIPMODE=1", 2000, "OK", "ERROR"))
      {
        print_lcd("Connecting host");
        
        String cipstart = "AT+CIPSTART=\"TCP\",\"";
        cipstart += HOST_BOOTLOADER;
        cipstart += "\",";
        cipstart += PORT_BOOTLOADER;
        if (send_command(cipstart, 5000, "OK", "ERROR"))
          if (send_command("AT+CIPSEND", 2000, ">", "ERROR"))
          {
            print_lcd("Init protocol");
            if (send_command("hello", 2000, "welcome", "error"))
              if (send_command("Arduino_remote_example.cpp.hex", 2000, "ok", "error"))
                return true;
          }
      }
            
  return false;
}
//-----------------------------------------------------------------------------------------------------------------------------------
/*
Parameters:
  Nothing
Returns: 
  True if all commands were successfully, otherwise False.
Description: 
  It sends a string to the remote host and show it in the display.
*/
boolean test()
{
  String command = "AT+CIPSEND=";
  String to_send = "hello guys! ";
  to_send += counter;
  command += to_send.length() + 2;
  
  if (send_command(command, 2000, ">", "ERROR"))
    if (send_command(to_send + "\r\n", 2000, "OK", "ERROR"))
    {
      lcd.clear();
      lcd.print(to_send);
      counter++;
      return true;
    }
  
  return false;
}
//-----------------------------------------------------------------------------------------------------------------------------------
void setup()
{
  pinMode(13, OUTPUT);
  Serial.begin(115200);
  lcd.begin(16, 2);
  lcd.print("Init WI07C...");
  
  // Remove any garbage from the RX buffer
  delay(3000);
  while(Serial.available() > 0) Serial.read();
  
  ok = init_commands();
}
//-----------------------------------------------------------------------------------------------------------------------------------
void loop()
{
  if(ok)
  {
    digitalWrite(13, HIGH);
    ok = test();
    if(ok && look_for("reboot", 5000))
    {
      if(boot_commands())
      {
        pinMode(12, OUTPUT);
        digitalWrite(12, LOW);
        for(;;);
      }
      else
      {
        ok = false;
      }
    }
  }  
  else
  {
    digitalWrite(13, LOW);
    lcd.clear();
    lcd.print("Error sending");
    lcd.setCursor(0, 1);
    lcd.print("AT commands");
    for(;;);
  }
}

100

101

102

103

104

105

106

107

108

109

110

111

112

113

114

115

116

117

118

119

120

121

122

123

124

125

126

127

128

129

130

131

132

133

134

135

136

137

138

139

140

141

142

143

144

145

146

147

148

149

150

151

152

153

154

155

156

157

158

159

160

161

162

163

164

165

166

167

168

169

170

171

172

173

174

175

176

177

178

179

180

181

182

183

184

185

186

187

188

189

190

191

192

193

194

195

196

197

198

199

200

201

202

203

204

205

206

207

208

209

210

211

212

213

214

215

216

217

218

219

220

221

222

223

224

225

226

227

228

229

230

231

232

233

234

235

236

237

238

239

240

241

242

243

244

245

246

247

248

249

250

251

252

253

254

255

256

257

258

259

260

261

262

263

264

265

266

267

268

269

270

271

272

273

274

275

276

277

278

279

280

281

282

283

284

285

286

287

288

289

290

291

292

293

294

295

296

297

298

299

300

301

// This program is free software: you can redistribute it and/or modify

// it under the terms of the GNU General Public License as published by

// the Free Software Foundation, either version 3 of the License, or

// (at your option) any later version.

// This program is distributed in the hope that it will be useful,

// but WITHOUT ANY WARRANTY; without even the implied warranty of

// MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the

// GNU General Public License for more details.

// You should have received a copy of the GNU General Public License

// along with this program. If not, see .

#include<LiquidCrystal.h>

#define SEARCH_AFTER_RESET"ready"

#define INTRO"\r\n"

#define AP_NORMAL"SISTEMASORP"

#define PWD_NORMAL"mypassword"

#define HOST_NORMAL"192.168.1.33"

#define PORT_NORMAL"49000"

#define AP_BOOTLOADER"SISTEMASORP"

#define PWD_BOOTLOADER"mypassword"

#define HOST_BOOTLOADER"192.168.1.33"

#define PORT_BOOTLOADER"50000"

booleanok=false;

intcounter=0;

LiquidCrystal lcd(2,3,4,5,6,7);

//-----------------------------------------------------------------------------------------------------------------------------------

Parameters:

show: The string to be printed.

Returns:

Nothing.

Description:

It clears the LCD and print the string.

voidprint_lcd(Stringshow)

{

lcd.clear();

lcd.print(show);

}

//-----------------------------------------------------------------------------------------------------------------------------------

Parameters:

command: The string to send.

timeout: The maximum time in milliseconds the function can be running before a time out.

wait_for1: The search string when the command succeeded.

wait_for1: The search string when the command failed.

Returns:

The string contained in wait_for1, wait_for2 or the string TIMEOUT.

Description:

It sends the command trough the serial port and waits for one of the expected strings or exit with timeout

Stringsend(Stringcommand,inttimeout,Stringwait_for1,Stringwait_for2)

{

unsignedlongtime=millis();

Stringreceived="";

Serial.print(command);

Serial.print(INTRO);

while(millis()<(time+timeout))

{

if(Serial.available()>0)

{

received.concat(char(Serial.read()));

if(received.indexOf(wait_for1)>-1)

{

returnwait_for1;

}

elseif(received.indexOf(wait_for2)>-1)

{

returnwait_for2;

}

return"TIMEOUT";

}

//-----------------------------------------------------------------------------------------------------------------------------------

Parameters:

wait_for: The search string.

timeout: The maximum time in milliseconds the function can be running before a time out.

Returns:

True if the string was found, otherwise False.

Description:

It waits for the expected string.

booleanlook_for(Stringwait_for,inttimeout)

{

unsignedlongtime=millis();

Stringreceived="";

while(millis()<(time+timeout))

{

if(Serial.available()>0)

{

received.concat(Serial.readString());

if(received.indexOf(wait_for)>-1)

{

returntrue;

}

Ip Pública	3.21.162.87
Navegador	Mozilla/5.0 AppleWebKit/537.36 (KHTML, like Gecko; compatible; ClaudeBot/1.0; +claudebot@anthropic.com)
País	United States
Ciudad	Seattle